// PoVRay 3.5 Scene File "hyperboloid.pov"
// created by Friedrich A. Lohmueller  
// Date:   August 2oo2
//--------------------------------------------------------------------------
#version 3.5;
global_settings {  assumed_gamma 1.5 }
//--------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
//--------------------------------------------------------------------------
// camera ------------------------------------------------------------------
#declare Camera0 = camera {ultra_wide_angle angle 27           // front view
                        location  <0.0 , 5.5 ,-6.0>
                        right     x*image_width/image_height
                        look_at   <-0.25 , 1.65 , 0.0>}
camera{Camera0}
// sun ---------------------------------------------------------------------
light_source{<1500,2500,-2500> color White}
// sky ---------------------------------------------------------------------
sphere{<0,0,0>,1 hollow 
              texture{pigment{gradient <0,1,0>  turbulence 0.5 
                              color_map{[0 color White]
                                        [0.5 color Scarlet*1.25 ]
                                        [1 color White]
                                       }
                              scale 1.5 translate<0,0,0>
                              quick_color White }
                      finish {ambient 1 diffuse 0}
                     } 
           scale 10000}
//--------------------------------------------------------------------------

#declare Hyperboloid =
union{
#declare Nr = 0;     // start
#declare EndNr = 60; // end
#while (Nr< EndNr+1) 
 cylinder {<cos(radians(Nr*360/EndNr)),0,sin(radians(Nr*360/EndNr))>,
           <cos(radians((Nr+EndNr/3)*360/EndNr)),2,sin(radians((Nr+EndNr/3)*360/EndNr))>,0.01 
           texture{pigment{color White}
                   finish {ambient 0.25 diffuse 0.75 phong 1}}
          }

 #declare Nr = Nr + 1;  // next Nr

#end // --------------- end of loop 
 }
 

object { Hyperboloid translate<0,0.5,0> }
object { Hyperboloid scale<-1,1,1> translate<0,0.5,0> }
//---------------------------------------------------------------------------------------- end